RPG

189. 印刷出力だけの最も簡単な RPG プログラム

あるデータ・ベースをキー順に読んで印刷出力するだけのRPGプログラムは
どのように作成すればよいだろうか ?
ここでは最も簡単な印刷出力を行う RPG ソースの例を紹介する。
下記のようにデータ・ベース SHOHIN を IP で呼んでそのまま印刷出力するだけである。
演算命令は何も要らない ! しかしちゃんと用紙サイズのオーバー・フローも立派に処理されている。
RPG は、実はこのようにシンプルな開発言語である。
RPG がまだ不慣れな人でも、あるいは何十年の開発経験を積んだ人であっても
このように簡単であるのは驚いて頂けるかも知れない。

【例】商品マスターを印刷出力するサンプル・ソース
------------------------------------------------------------------------------------
0001.00 H DFTNAME(TESTRPT) DATEDIT(*YMD/)                                          
0002.00 F**********  商品一覧表 ***********************************************    
0003.00 FSHOHIN    IP   E           K DISK                                         
0004.00 FQPRINT    O    F  132        PRINTER OFLIND(*INOF)                        
0005.00 F                                     FORMLEN(66)                          
0006.00 F                                     FORMOFL(62)                          
0007.00 F*****************************************************************         
0008.00 OQPRINT    H    1P                     2 06                                
0009.00 O         OR    OF                                                         
0010.00 O                       UDATE         Y      8                             
0011.00 O                                           14 ' 作成 '                    
0012.00 O                                           82 '* 商品マスター一覧表 *'    
0013.00 O                                          128 'PAGE.'                     
0014.00 O                       PAGE          Z    131                             
0015.00 O          H    1P                     2                                   
0016.00 O         OR    OF                                                         
0017.00 O                                           12 ' 商品コード '              
0018.00 O                                           34 ' 商品名 '                  
0019.00 O                                           68 ' 単価 '                    
0020.00 O                                           80 ' 品種コード '              
0021.00 O          D                           2                                   
0022.00 O                       SHCODE              11                             
0023.00 O                       SHNAME              46                             
0024.00 O                       SHTANK        J     70                             
0025.00 O                       SHSCOD              78                             
------------------------------------------------------------------------------------