A****************************************************************          
     A**  TESTPRTF2 :  売掛元帳                                     **          
     A**                                                            **          
     A**  見出し 1                                                  **          
     A****************************************************************          
     A          R #HED1                                                         
     A                                      OVERLAY('/SPOOLWTR/URIKAKE.JPG' -   
     A                                       0.02 0.5)                          
     A            WLPAGE         4  0     73TEXT(' ページ ')                    
     A                                      EDTCDE(3)                           
     A                                     4' 大阪市天王寺区通天閣上る '        
     A                                      SKIPB(5)                            
     A** LINE 9                                                                 
     A            WLHD02         2         4TEXT(' 店コード ')                  
     A                                      SKIPB(8)                            
     A                                     6'-'                                 
     A            WLHD03         2         7TEXT(' 地区コード ')                
     A                                     9'-'                                 
     A            WLHD04         5         8TEXT(' 得意先コード ')              
     A            WLHD05        32        15TEXT(' 得意先名 ')                  
     A****************************************************************          
     A**  明細行 1                                                  **          
     A****************************************************************          
     A          R #DTL1                                                         
     A                                    13' 前　残 '                          
     A                                      SKIPB(13)                           
     A            WLD101        10  0     56TEXT(' 前残 ')                      
     A                                      EDTCDE(P)                           
     A****************************************************************          
     A**  明細行 2                                                  **          
     A****************************************************************          
     A          R #DTL2                                                         
     A                                     3' '                                 
     A                                      SPACEB(1)                           
     A  12        WLD201         6  0      4TEXT(' 伝票日付 ')                  
     A                                      EDTWRD('0  /  /  ')                 
     A            WLD202         9  0     12TEXT(' 伝票�Y ')                    
     A                                      EDTCDE(Z)                           
     A            WLD203         2        22TEXT(' 区分 ')                      
     A N21        WLD204         9  0     25TEXT(' 売上／仕入 ')                
     A                                      EDTCDE(P)                           
     A N22        WLD205         9  0     36TEXT(' 入金／支払 ')                
     A                                      EDTCDE(P)                           
     A N23        WLD206         8  0     46TEXT(' 消費税 ')                    
     A                                      EDTCDE(P)                           
     A N24        WLD207        10  0     56TEXT(' 残高 ')                      
     A                                      EDTCDE(P)                           
     A N13        WLD208        11        64TEXT(' 備考 ')                      
     A  13        WLD209        10  0     64TEXT(' 備考 ')                      
     A                                      EDTCDE(P)                           
     A****************************************************************          
     A**  合計行                                                    **          
     A****************************************************************          
     A          R #TTL                                                          
     A                                    14'*********'                         
     A                                      SPACEB(2)                           
     A            WLT104         9  0     25TEXT(' 売上／仕入 ')                
     A                                      EDTCDE(P)                           
     A            WLT105         9  0     36TEXT(' 入金／支払 ')                
     A                                      EDTCDE(P)                           
     A            WLT106         8  0     46TEXT(' 消費税 ')                    
     A                                      EDTCDE(P)                           
     A            WLT107        10  0     56TEXT(' 残高 ')                      
     A                                      EDTCDE(P)                           
     A****************************************************************          
     A**  ダミー                                                    **          
     A****************************************************************          
     A          R #DMY                                                          
     A**                                                                        
     A                                      ' '                                 
     A                                      SPACEB(1)