A***************************************************************           
     A*    PGM007P      :   商品マスター一覧表                                  
     A*     ソース      :  QTRSRC/QPRTSRC(PGM007P)                              
     A*     使用目的    :   照会 (*INQUIRY)                                     
     A*     作成日      :  2024/10/26          6:52:00                          
     A*     作成者      :  QTR                                                  
     A*     コンパイル  :                                                       
     A*       CRTPRTF FILE(QTROBJ/QPRTAFP) SRCFILE(QTRSRC/QPRTSRC)              
     A*       DEVTYPE(*AFPDS) CDEFNT(QFNT61/X0N16V) IGCDTA(*YES)                
     A*       IGCCDEFNT(QFNT61/X0M32F) LVLCHK(*NO) AUT(*ALL)                    
     A*                                                                         
     A***************************************************************           
     A*( 見出行 )                                                               
      *    ---------------------------                                          
     A          R PRTHEAD                                                       
      *    ---------------------------                                          
     A                                      SKIPB(03)                           
     A                                     1'PRTAFP'                            
     A                                    66' 商品マスター一覧表 '              
     A                                      CHRSIZ(2 2)                         
     A                                   120'PAGE.'                             
     A                                    +1PAGNBR                              
     A                                      EDTCDE(Z)                           
     A                                      SPACEA(1)                           
     A            SYSNAM         8A      120TEXT(' システム名 ')                
     A                                      CHRSIZ(2 2)                         
     A                                      COLOR(BLU)                          
     A                                      SPACEA(1)                           
     A                                   120DATE EDTCDE(Y)                      
     A                                      SPACEA(1)                           
     A                                   120TIME                                
     A                                      SPACEA(1)                           
     A                                     1' コード '                          
     A                                    14' 商品名 '                          
     A                                    38' 単価 '                            
     A                                    45' 品種コード '                      
     A                                      SPACEA(1)                           
     A*( 明細行 )                                                               
      *    ---------------------------                                          
     A          R DETAIL                                                        
      *    ---------------------------                                          
     A            SHCODE        10A        1TEXT(' 商品コード ')                
     A            SHNAME        24O       11TEXT(' 商品名 ')                    
     A            SHTANK         7S 0     35TEXT(' 単価 ')                      
     A                                      EDTCDE(J)                           
     A            SHSCOD         4A       45TEXT(' 品種コード ')                
     A            HNSNAM        14O       50TEXT(' 品種名 ')                    
     A                                      SPACEA(2)                           
     A*( 小計行 )                                                               
      *    ---------------------------                                          
     A          R SUMMRY                                                        
      *    ---------------------------                                          
     A                                    11'*  小計 *'                         
     A            SHOKEI         9S 0     33TEXT(' 小計 ')                      
     A                                      EDTCDE(J)                           
     A                                      SPACEA(2)                           
     A*( 最終行 )                                                               
     A          R ENDPRT                                                        
     A                                    11'** 合計 **'                        
     A            GOKEI          9S 0     33TEXT(' 合計 ')                      
     A                                      EDTCDE(J)                           
     A                                      SPACEA(2)                           
     A                                    32'*  *  *  *  *'                     
     A                                    +1' 報　　告　　書　　の　　終　　り '
     A                                    +1' *  *  *  *  *'                    
     A                                      SPACEA(1)