PGM                                                                
/*-------------------------------------------------------------------*/         
/*   ORDERFCL   :  注文書サンプルの印刷                              */         
/*                                                                   */         
/*   2020/07/07  作成                                                */         
/*-------------------------------------------------------------------*/         
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(132)                          
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)                          
             DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)                       
             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(132)                       
             DCL        VAR(&TYPE) TYPE(*CHAR) LEN(1)                           
             DCL        VAR(&TOPGMQ) TYPE(*CHAR) LEN(10)                        
             DCL        VAR(&MSGTYPE) TYPE(*CHAR) LEN(10) +                     
                          VALUE('*ESCAPE   ')                                   
             DCL        VAR(&ERR) TYPE(*CHAR) LEN(1)                            
             DCL        VAR(&NULL4) TYPE(*CHAR) LEN(4) +                        
                          VALUE(X'00000000')                                    
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))                 
                                                                                
/*( 環境の取得 )*/                                                              
             RTVJOBA    TYPE(&TYPE)                                             
             IF         COND(&TYPE *EQ '0') THEN(DO) /*  バッチ  */             
             CHGVAR     VAR(&TOPGMQ) VALUE('*SYSOPR   ')                        
             ENDDO      /*  バッチ  */                                          
             ELSE       CMD(DO) /*  対話式  */                                  
             CHGVAR     VAR(&TOPGMQ) VALUE('*TOPGMQ   ')                        
             ENDDO      /*  対話式  */                                          
                                                                                
/*( 入力パラメータの検査 )*/                                                    
                                                                                
/*( プログラムの実行 )*/                                                        
             OVRPRTF    FILE(ORDERF) HOLD(*YES) SECURE(*YES) +                  
                          OVRSCOPE(*JOB)                                        
             CALL       PGM(QTROBJ/ORDERF)                                      
             DLTOVR     FILE(ORDERF) LVL(*JOB)                                  
             MONMSG     CPF9800                                                 
             CVTSPLF    SPLF(ORDERF) SPLNO(*LAST) OUTPUT(*PDF) +                
                          OPTION(*DISPLAY)                                      
             DLTSPLF    FILE(ORDERF) SPLNBR(*LAST)                              
             CHGVAR     VAR(&MSGTYPE) VALUE('*DIAG     ')                       
             CHGVAR     VAR(&MSG) VALUE(' 注文書を印刷しました。 ')             
             GOTO       SNDMSG                                                  
                                                                                
 ERROR:      RCVMSG     MSGTYPE(*LAST) RMV(*NO) MSG(&MSG) +                     
                          MSGDTA(&MSGDTA) MSGID(&MSGID) MSGF(&MSGF) +           
                          MSGFLIB(&MSGFLIB)                                     
 SNDMSG:     IF         COND(&MSGID *EQ ' ') THEN(DO)                           
             SNDPGMMSG  MSGID(CPF9897) MSGF(QCPFMSG) MSGDTA(&MSG) +             
                          TOMSGQ(&TOPGMQ) MSGTYPE(&MSGTYPE)                     
             MONMSG     MSGID(CPF2400) EXEC(RETURN)                             
             ENDDO                                                              
             ELSE       CMD(DO)                                                 
             SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +                    
                          MSGDTA(&MSGDTA) TOMSGQ(&TOPGMQ) +                     
                          MSGTYPE(&MSGTYPE)                                     
             MONMSG     MSGID(CPF2400) EXEC(RETURN)                             
             ENDDO                                                              
             ENDPGM