H            Y/                                                      SMPRIN
     F**********  サンプル・データ印刷        *************************         
     FSHOHIN  IF  E           K        DISK                                     
     FQPRINT  O   F     132     OF    LPRINTER                                  
     F*****************************************************************         
     F*  これは SAMPLEDB  を外部入力指定された FRMCOD から                      
     F*  最大 20 件のレコードを読み取って印刷する                               
     F*  SMPRINT という名前のプログラムです。                                   
     F*  SMPRINT は CLP: SMPRINTCL  によって呼び出されたときは                  
     F*  WEB の配信処理として印刷結果は SPOOL ライターによって                  
     F*  HTML に変更されてブラウザに戻されます。                                
     E                    HDR     1   1 32                見出し                
     LQPRINT   66FL 62OL                                                        
     C*----------------------------------------------------+                    
     C           *ENTRY    PLIST                           |                    
     C                     PARM           FRMCOD 10        |                    
     C*----------------------------------------------------+                    
     C******************************************************                    
     C*            明　　細　　演　　算                                         
     C******************************************************                    
     C*----------------------------------------------------+                    
     C           SETKEY    KLIST                                                
     C                     KFLD           SHCODE                                
     C*----------------------------------------------------+                    
     C                     MOVELFRMCOD    SHCODE                                
     C*          FRMCOD    DSPLY          ANS     1                             
     C           SETKEY    SETLLSHOHIN                                          
     C           1         DO   20        N       40       1-20 LOOP            
     C                     SETOF                     50                         
     C                     READ SHOHIN                   50                     
     C   50                LEAVE                                                
     C*                                                                         
     C*( 明細印刷 )                                                             
     C*----------------------------------------------------+                    
     C                     SETON                     42    |                    
     C                     EXSR OUTPUT                     | 明細印刷           
     C*----------------------------------------------------+                    
     C                     ADD  1         KENSU   70        件数                
     C                     ADD  SHTANK    TANKEI  70        単価計              
     C                     END                             1-20 LOOP            
     C*( 小計 )                                                                 
     C*                                                                         
     C           END       TAG                                                  
     C*( T-LR 最終合計 )                                                        
     C*----------------------------------------------------+                    
     C                     SETON                     49    |                    
     C                     EXSR OUTPUT                     | 件数印刷           
     C*----------------------------------------------------+                    
     C                     SETON                     LR                         
     C                     RETRN                                                
     C******************************************************                    
     C           *INZSR    BEGSR                                                
     C******************************************************                    
     CSR                   ENDSR                                                
     C******************************************************                    
     C           OUTPUT    BEGSR                                                
     C******************************************************                    
     CSRN40                SETON                     4041                       
     CSR                   EXCPT                                                
     CSR OF                SETOF                     40OF                       
     CSR                   SETOF                     414243                     
     CSR                   SETOF                     444546                     
     CSR                   SETOF                     474849                     
     CSR                   ENDSR                                                
     OQPRINT  E  206   41                                                       
     O                         UDATE Y    8                                     
     O                                   14 ' 作成 '                            
     O                         HDR,1     82                                     
     O                                  129 'PAGE.'                             
     O                         PAGE  Z  132                                     
     O        E  1     41                                                       
     O        E  1     41                                                       
     O                                   24 '------------------------'          
     O                                   48 '------------------------'          
     O                                   72 '------------------------'          
     O                                   96 '------------------------'          
     O                                  120 '------------------------'          
     O                                  132 '------------'                      
     O        E  1     41                                                       
     O                                   12 ' 商品コード '                      
     O                                   21 ' 商品名 '                          
     O                                   62 ' 単価 '                            
     O                                   75 ' 品種コード '                      
     O        E  2     41                                                       
     O                                   24 '------------------------'          
     O                                   48 '------------------------'          
     O                                   72 '------------------------'          
     O                                   96 '------------------------'          
     O                                  120 '------------------------'          
     O                                  132 '------------'                      
     O*( 明細行 )                                                               
     O        E  1     42                                                       
     O                         SHCODE    12                                     
     O                         SHNAME    50                                     
     O                         SHTANKJ   62                                     
     O                         SHSCOD    68                                     
     O        E  1     42                                                       
     O        E  1     49                                                       
     O                                   20 ' 【合計】 '                        
     O                         TANKEIJ   62                                     
     O        E  1     49                                                       
     O                                   40 ' 処理件数 '                        
     O                                   57 '. . . . . . . . .'                 
     O                         KENSU 2   65                                     
**  HDR                                                                         
 サンプル・データ印刷