H DFTNAME(SFL004) DATEDIT(*YMD/)                                                               
     F**********  商品マスター照会 ************************************                             
     FSFL004FM  CF   E             WORKSTN                                                          
     F                                     SFILE(SFREC01:RRN1)                                      
     F                                     INFDS(INFDS)                                             
     FSHOHIN    IF   E           K DISK                                                             
     F*****************************************************************                             
     D*  TOPRRN: 今表示している ｻﾌﾞ･ﾌｧｲﾙ の先頭の RRN                                               
     D INFDS           DS                                                                           
     D  LINE                 370    371B 0                                                          
     D  BRRN                 376    377B 0                                                          
     D  TOPRRN               378    379B 0                                                          
                                                                                                    
     D* 作業変数の定義                                                                              
     D RRN1            S              4S 0 INZ                                                      
     D SFLPAG          S              4S 0 INZ(13)                                                  
     D STRRRN          S              4S 0 INZ(1)                                                   
     D ENDRRN          S              4S 0 INZ                                                      
     C     *LOVAL        SETLL     SHOHIN                                                           
     C                   EXSR      SFLCLR                                                           
     C*   : ファイルの読み取り                                                                      
     C                   EXSR      READ                                                             
     C*( サブ・ファイルの表示 )                                                                     
     C*----------------------------------------------------+                                        
     C     DSPLY         TAG                                                    |                   
     C                   SETON                                        4142      |SFL-DSPLY          
     C                   EXFMT     SFCTL01                                      |                   
     C                   SETOFF                                       4142      |                   
     C*----------------------------------------------------+                                        
     C*( CF03 )- 終了                                                                               
     C     *IN03         IFEQ      *ON                                          CF03                
     C                   SETON                                        LR                            
     C   LR              RETURN                                                                     
     C                   END                                                    CF03                
     C*( CF04 )- プロンプト要求                                                                     
     C     *IN04         IFEQ      *ON                                          CF03                
     C     LINE          DIV       256           LIN               3 0                              
     C                   MVR                     POS               3 0                              
     C     LIN           SUB       8             RRN1                                               
     C                   ADD       TOPRRN        RRN1                                               
     C                   SETOFF                                       90                            
     C     RRN1          CHAIN     SFREC01                            90                            
     C     *IN90         IFEQ      *OFF                                                             
     C     SHCODE        DSPLY                                                                      
     C                   END                                                                        
     C                   END                                                    CF03                
     C*( ROLL-UP )                                                                                  
     C     *IN14         IFEQ      *ON                                          CF03                
     C                   EXSR      READ                                                             
     C                   END                                                    CF03                
     C*( 実行キー )                                                                                 
     C                   GOTO      DSPLY                                                            
     C     END           TAG                                                                        
     C******************************************************                                        
     C     READ          BEGSR                                                                      
     C******************************************************                                        
     C     STRRRN        ADD       13            ENDRRN                                             
     C     STRRRN        DO        ENDRRN        RRN1                           READ                
     C                   SETOFF                                       50                            
     C                   READ      SHOHIN                                 50                        
     C   50              SETOFF                                       45                            
     C   50              LEAVE                                                                      
     C                   MOVE      RRN1          GYO                                                
     C*----------------------------------------------------+                                        
     C                   WRITE     SFREC01                                      |                   
     C*----------------------------------------------------+                                        
     C                   END                                                    READ                
     C                   ADD       SFLPAG        STRRRN                                             
     C     REDEND        ENDSR                                                                      
     C******************************************************                                        
     C     SFLCLR        BEGSR                                                                      
     C******************************************************                                        
     C                   SETON                                        4445      |                   
     C                   WRITE     SFCTL01                                      |                   
     C                   SETOFF                                       44        |                   
     C                   ENDSR