H DATEDIT(*YMD/) DFTNAME(RTVJOBA)                                                              
     F********** ジョブ情報の取得 ******************************************                        
     F*                                                                                             
     F**********************************************************************                        
      /COPY QSYSINC/QRPGLESRC,QUSRJOBI                                                              
                                                                                                    
     D JOBINFO         DS                                                                           
     D  JOB                    1     10                                                             
     D  USER                  11     20                                                             
     D  NBR                   21     26                                                             
                                                                                                    
     D APIERR          DS                                                                           
     D  GETBYT                 1      4B 0 INZ(16)                                                  
     D  AVLBYT                 5      8B 0 INZ(0)                                                   
     D  ECPERR                 9     15                                                             
     D  ECP                   16     16                                                             
                                                                                                    
     D RCVLEN          S              4B 0 INZ                                                      
                                                                                                    
     C*----------------------------------------------------+                                        
     C     *ENTRY        PLIST                                                  |                   
     C                   PARM                    JOB_NAME         10            |                   
     C                   PARM                    USR_NAME         10            |                   
     C                   PARM                    NBR_NAME          6            |                   
     C                   PARM                    OUTQ             10            |                   
     C                   PARM                    OUTQLIB          10            |                   
     C                   PARM                    DATE              6            |                   
     C                   PARM                    TYPE              1            |                   
     C                   PARM                    PRTDEV           10            |                   
     C                   PARM                    LANGID            3            |                   
     C                   PARM                    CNTRYID           2            |                   
     C                   PARM                    CCSID             5 0          |                   
     C                   PARM                    DFTCCSID          5 0          |                   
     C                   PARM                    CYMDDATE          8            |                   
     C                   PARM                    SBMMSGQ          10            |                   
     C                   PARM                    SBMMSGQLIB       10            |                   
     C*----------------------------------------------------+                                        
     C*( ジョブ属性検索 )                                                                           
     C                   MOVEL     JOB_NAME      JOB                                                
     C                   MOVEL     USR_NAME      USER                                               
     C                   MOVEL     NBR_NAME      NBR                                                
     C                   EVAL      RCVLEN = %SIZE(QUSI030000)                                       
     C*----------------------------------------------------+                                        
     C                   CALL      'QUSRJOBI'                                                       
     C                   PARM                    QUSI030000                                         
     C                   PARM                    RCVLEN                                             
     C                   PARM      'JOBI0300'    FORMAT            8                                
     C                   PARM                    JOBINFO                                            
     C                   PARM                    JOBID            16                                
     C                   PARM                    APIERR                                             
     C*----------------------------------------------------+                                        
     C                   EVAL      JOBID = QUSIJID02                                                
     C                   EVAL      OUTQ  = QUSON                                                    
     C                   EVAL      OUTQLIB = QUSOL                                                  
     C                   EVAL      DATE  = QUSJD                                                    
     C                   IF        QUSJT05 = 'B'                                                    
     C                   EVAL      TYPE = '0'                                                       
     C                   ELSE                                                                       
     C                   EVAL      TYPE = '1'                                                       
     C                   ENDIF                                                                      
     C                   EVAL      SBMMSGQ = QUSSMN                                                 
     C                   EVAL      SBMMSGQLIB = QUSSML                                              
     C                   EVAL      PRTDEV  = QUSPDN                                                 
     C                   MOVE      *BLANKS       JOBINFO                                            
     C                   MOVEL     '*INT'        JOB                                                
     C*----------------------------------------------------+                                        
     C                   CALL      'QUSRJOBI'                                                       
     C                   PARM                    QUSI0400                                           
     C                   PARM                    RCVLEN                                             
     C                   PARM      'JOBI0400'    FORMAT            8                                
     C                   PARM                    JOBINFO                                            
     C                   PARM                    JOBID            16                                
     C                   PARM                    APIERR                                             
     C*----------------------------------------------------+                                        
     C                   EVAL      LANGID = QUSLID01                                                
     C                   EVAL      CNTRYID = QUSCID01                                               
     C                   EVAL      CCSID  = QUSCCSID07                                              
     C                   EVAL      DFTCCSID = QUSDCCSI                                              
     C                   SETON                                        LR                            
     C                   RETURN