A                                      DSPSIZ(24 80 *DS3)                  
     A                                      MSGLOC(24)                          
     A                                      PRINT                               
     A          R DSPHEAD                                                       
     A                                      TEXT(' 初期画面 ')                  
     A*            11:59:33    QSECOFR     REL-R06M00  5714-UT1                 
     A                                      CF03(03 ' 終了 ')                   
     A                                      BLINK                               
     A                                  1 27' 商品マスターの登録 '              
     A                                      DSPATR(RI)                          
     A                                  2  2' 商品コード '                      
     A            SHCODE        10A  B  2 15TEXT(' 商品コード ')                
     A                                 11 13' 登録または変更するコードを +      
     A                                       入れて実行キーを押しなさい '       
     A                                      DSPATR(HI)                          
     A                                 23  2'F3= 終了 '                         
     A          R DSPDTA01                                                      
     A*%%TS  SD  19940302  221529  QTR         REL-V2R2M0  5738-PW1             
     A                                      TEXT(' 明細画面 01')                
     A                                      CF03(03 ' 終了 ')                   
     A                                      CF10(10 ' 更新 ')                   
     A                                      CF23(23 ' 削除 ')                   
     A                                      CF12(12 ' 前画面 ')                 
     A                                      SETOF(99)                           
     A                                      BLINK                               
     A                                  1 27' 商品マスターの登録 '              
     A                                      DSPATR(RI)                          
     A            DSPMSG         6A  O  1 72TEXT(' 維持モード ')                
     A                                      DSPATR(HI)                          
     A                                  2  2' 商品コード '                      
     A            SHCODE        10A  O  2 15TEXT(' 商品コード ')                
     A                                  5 10' 商品名 '                          
     A            SHNAME        24O  B  5 24TEXT(' 商品名 ')                    
     A                                  8 10' 単価 '                            
     A            SHTANK         7Y 0B  8 24TEXT(' 単価 ')                      
     A                                      CHECK(RB)                           
     A                                      EDTCDE(K)                           
     A                                      DSPATR(CS)                          
     A                                 11 10' 品種コード '                      
     A            SHSCOD         4A  B 11 24TEXT(' 品種コード ')                
     A  93                                  ERRMSG(' 品種コードの誤りです。    -
     A                                                                ' 93)     
     A                                      VALUES('001' '002' '003' '004')     
     A            HNSNAM        14A  O 11 31TEXT(' 品種名 ')                    
     A                                 23  2'F3= 終了 '                         
     A                                 23 35'F10= 更新 '                        
     A                                 23 53'F23= 削除 '                        
     A                                 23 69'F12= 前画面 '                      
     A          R ENDOPT                                                        
     A*%%TS  SD  19930612  150356  NIK         REL-V3R2M0  5738-PW1             
     A                                      TEXT(' 終了画面 ')                  
     A                                      CF03(03 ' 終了 ')                   
     A                                      CF12(12 ' 前画面 ')                 
     A                                  1 34' 終了 '                            
     A                                      COLOR(PNK)                          
     A                                      DSPATR(HI)                          
     A                                  3  2' 処理されたレコード数 '            
     A                                  5 10' 追加  . . . . . :'                
     A            ADDREC         5Y 0O  5 35EDTCDE(4)                           
     A                                  6 10' 変更  . . . . . :'                
     A            CHGREC         5Y 0O  6 35EDTCDE(4)                           
     A                                  7 10' 削除  . . . . . :'                
     A            DLTREC         5Y 0O  7 35EDTCDE(4)                           
     A                                 11  2' 選択項目を打鍵して，実行キーを押 +
     A                                       してください。 '                   
     A                                      COLOR(BLU)                          
     A                                 13  5' データ入力の終了  . . . . . .'    
     A            ANS            1A  B 13 39VALUES('Y' 'N')                     
     A                                 13 53'Y=YES, N=NO'                       
     A                                 23  2'F3= 終了 '                         
     A                                      COLOR(BLU)                          
     A                                 23 15'F12= 前画面 '                      
     A                                      COLOR(BLU)