PGM        PARM(&FILFILLIB &MBR)                                   
/*----------------------------------------------------------------------*/      
/*   TESTREADCL :  C 関数による読取り                                   */      
/*                                                                      */      
/*   2021/11/25  作成                                                   */      
/*----------------------------------------------------------------------*/      
             DCL        VAR(&FILFILLIB) TYPE(*CHAR) LEN(20)                     
             DCL        VAR(&FILE) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&FILLIB) TYPE(*CHAR) LEN(10)                        
             DCL        VAR(&MBR) TYPE(*CHAR) LEN(10)                           
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(132)                          
             DCL        VAR(&STMMSG) TYPE(*CHAR) LEN(132)                       
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)                          
             DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)                       
             DCL        VAR(&MSGKEY) TYPE(*CHAR) LEN(4)                         
             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(132)                       
             DCL        VAR(&ERRDTA) TYPE(*CHAR) LEN(132)                       
             DCL        VAR(&TYPE) TYPE(*CHAR) LEN(1)                           
             DCL        VAR(&TOPGMQ) TYPE(*CHAR) LEN(10)                        
             DCL        VAR(&MSGTYPE) TYPE(*CHAR) LEN(10) +                     
                          VALUE('*ESCAPE   ')                                   
             DCL        VAR(&ERR) TYPE(*CHAR) LEN(1)                            
             DCL        VAR(&NULL4) TYPE(*CHAR) LEN(4) +                        
                          VALUE(X'00000000')                                    
             DCL        VAR(&APIERR) TYPE(*CHAR) LEN(116) +                     
                          VALUE(X'000074') /* 2 進数  */                        
             MONMSG     MSGID(CPF9999) EXEC(GOTO CMDLBL(ERROR))                 
                                                                                
/*( 環境の取得 )*/                                                              
             RTVJOBA    TYPE(&TYPE)                                             
             IF         COND(&TYPE *EQ '0') THEN(DO) /*  バッチ  */             
             CHGVAR     VAR(&TOPGMQ) VALUE('*SYSOPR   ')                        
             ENDDO      /*  バッチ  */                                          
             ELSE       CMD(DO) /*  対話式  */                                  
             CHGVAR     VAR(&TOPGMQ) VALUE('*TOPGMQ   ')                        
             ENDDO      /*  対話式  */                                          
                                                                                
/*( 入力パラメータの取得 )*/                                                    
             CHGVAR     VAR(&FILE) VALUE(%SST(&FILFILLIB 01 10))                
             CHGVAR     VAR(&FILLIB) VALUE(%SST(&FILFILLIB 11 10))              
                                                                                
/*( プログラムの実行 )*/                                                        
             CALL       PGM(TEST.COM/TESTREAD) PARM(&FILE &FILLIB +             
                          &MBR &ERR &MSG)                                       
             IF         COND(&ERR *EQ ' ') THEN(DO)                             
             CHGVAR     VAR(&MSGTYPE) VALUE('*DIAG     ')                       
             ENDDO                                                              
             IF         COND(&MSG *NE ' ') THEN(DO)                             
             GOTO       SNDMSG                                                  
             ENDDO                                                              
             RETURN                                                             
                                                                                
 ERROR:      RCVMSG     MSGTYPE(*LAST) RMV(*NO) KEYVAR(&MSGKEY) +               
                          MSGDTA(&MSGDTA) MSGID(&MSGID) MSGF(&MSGF) +           
                          MSGFLIB(&MSGFLIB)                                     
             IF         COND(&MSGID *EQ 'CPF9999') THEN(DO)                     
             CHGVAR     VAR(&ERRDTA) VALUE(&MSGDTA)                             
             RCVMSG     MSGTYPE(*PRV) MSGKEY(&MSGKEY) RMV(*NO) +                
                          MSG(&MSG) MSGDTA(&MSGDTA) MSGID(&MSGID) +             
                          MSGF(&MSGF) MSGFLIB(&MSGFLIB)                         
             CHGVAR     VAR(&STMMSG) VALUE(' プログラム ' *CAT +                
                          %SST(&ERRDTA 8 10) *TCAT +                            
                          ' のステートメント ' *CAT %SST(&ERRDTA +              
                          24 4) *CAT ' で次のエラーが発生しました。 ')          
             SNDPGMMSG  MSGID(CPF9897) MSGF(QCPFMSG) MSGDTA(&STMMSG) +          
                          TOMSGQ(&TOPGMQ) MSGTYPE(*DIAG)                        
             ENDDO                                                              
 SNDMSG:     IF         COND(&MSGID *EQ ' ') THEN(DO)                           
             SNDPGMMSG  MSGID(CPF9897) MSGF(QCPFMSG) MSGDTA(&MSG) +             
                          TOMSGQ(&TOPGMQ) MSGTYPE(&MSGTYPE)                     
             MONMSG     MSGID(CPF2400) EXEC(RETURN)                             
             ENDDO                                                              
             ELSE       CMD(DO)                                                 
             SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +                    
                          MSGDTA(&MSGDTA) TOMSGQ(&TOPGMQ) +                     
                          MSGTYPE(&MSGTYPE)                                     
             MONMSG     MSGID(CPF2400) EXEC(RETURN)                             
             ENDDO                                                              
             ENDPGM