PGM        PARM(&FILFILLIB &MBR &TOIPADRESS &TOPASS +              
                          &USER &PASSWORD &OPT &LOG)                            
/*---------------------------------------------------------*/                   
/*   SNDFTPF     :   FTP によるファイル送信                */                   
/*---------------------------------------------------------*/                   
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(80)                           
             DCL        VAR(&FILFILLIB) TYPE(*CHAR) LEN(20)                     
             DCL        VAR(&FILE) TYPE(*CHAR) LEN(10)                          
             DCL        VAR(&FILLIB) TYPE(*CHAR) LEN(10)                        
             DCL        VAR(&MBR) TYPE(*CHAR) LEN(10)                           
             DCL        VAR(&TOIPADRESS) TYPE(*CHAR) LEN(15)                    
             DCL        VAR(&TOPASS) TYPE(*CHAR) LEN(128)                       
             DCL        VAR(&USER) TYPE(*CHAR) LEN(13)                          
             DCL        VAR(&PASSWORD) TYPE(*CHAR) LEN(13)                      
             DCL        VAR(&OPT) TYPE(*CHAR) LEN(3)                            
             DCL        VAR(&LOG) TYPE(*CHAR) LEN(4)                            
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))                 
                                                                                
             CHGVAR     VAR(&FILE) VALUE(%SST(&FILFILLIB 01 10))                
             CHGVAR     VAR(&FILLIB) VALUE(%SST(&FILFILLIB 11 10))              
             IF         COND(&MBR *EQ '*FIRST    ') THEN(DO)                    
             RTVMBRD    FILE(&FILLIB/&FILE) MBR(*FIRST) RTNMBR(&MBR)            
             ENDDO                                                              
             CRTSRCPF   FILE(QTEMP/QFTPSRC) RCDLEN(228) IGCDTA(*YES) +          
                          AUT(*ALL)                                             
             MONMSG     CPF7300                                                 
             ADDPFM     FILE(QTEMP/QFTPSRC) MBR(FTPCMD)                         
             MONMSG     MSGID(CPF7300 CPF5800)                                  
             ADDPFM     FILE(QTEMP/QFTPSRC) MBR(FTPLOG)                         
             MONMSG     MSGID(CPF7300 CPF5800)                                  
             CLRPFM     FILE(QTEMP/QFTPSRC) MBR(FTPCMD)                         
             CLRPFM     FILE(QTEMP/QFTPSRC) MBR(FTPLOG)                         
             OVRDBF     FILE(QFTPSRC) TOFILE(QTEMP/QFTPSRC) +                   
                          MBR(FTPCMD) OVRSCOPE(*JOB)                            
             CALL       PGM(QUATTRO/SNDFTPF) PARM(&USER &PASSWORD +             
                          &FILE &FILLIB &MBR &TOPASS &OPT)                      
             DLTOVR     FILE(QFTPSRC) LVL(*JOB)                                 
 /*ﾗ SNDTCPFTP を実行 ﾝ*/                                                       
             CHGJOB CCSID(5035)                                                 
             OVRDBF     FILE(INPUT) TOFILE(QTEMP/QFTPSRC) +                     
                          MBR(FTPCMD) OVRSCOPE(*JOB)                            
             OVRDBF     FILE(OUTPUT) TOFILE(QTEMP/QFTPSRC) +                    
                          MBR(FTPLOG) OVRSCOPE(*JOB)                            
             STRTCPFTP  RMTSYS(*INTNETADR) INTNETADR(&TOIPADRESS)               
             DLTOVR     FILE(INPUT OUTPUT) LVL(*JOB)                            
             IF         COND(&LOG *EQ '*YES') THEN(DO)                          
             RUNQRY     QRY(*NONE) QRYFILE((QTEMP/QFTPSRC FTPLOG)) +            
                          OUTTYPE(*DISPLAY)                                     
             ENDDO                                                              
             CHGJOB CCSID(5026)                                                 
             CHGJOB CCSID(65535)                                                
                                                                                
 ERROR:      RCVMSG     RMV(*NO) MSG(&MSG)                                      
 SNDMSG:     SNDPGMMSG  MSG(&MSG) TOMSGQ(*SYSOPR)                               
             ENDPGM