コマンド

74. コマンド文書の生成(GENCMDDOC)

GENCMDDOCというコマンドはIBM提供のコマンドであり
IBMコマンドだけでなくユーザーが作成したコマンドも
文書化することができる。
このようにIBMからも文書化を支援するツールが
提供されている。
社内の文書化を勧めるならこのようなIBM提供の文書化ツールを
利用しない手はない。
すべての業務をコマンドから出発するようにしておけば
コマンドの文書化によって驚くほど文書化の効果がある。

▼ Chao!! のユーザーズ・ガイドはここから (これはオフィスクアトロのVer5.4でAM900~PM600まで公開しています)

[ GENCMDDOC(=Generate Command Documentation) の実行 ]

                        コマンド文書の生成  (GENCMDDOC)                    
                                                                           
 選択項目を入力して,実行キーを押してください。                            
                                                                           
 コマンド  . . . . . . . . . . .   DSPDBSREF      名前,総称* , *ALL      
  ライブラリー  . . . . . . . . . . .     CHAO.COM     名前 , *LIBL, *CURLIB    
 TO ディレクトリー   . . . . . .   /DOC/                                    
                                                                           
 TO ストリーム・ファイル   . . .   *CMD                                    
                                                                        
                                                                           
                                                                           
 ファイルの置き換え  . . . . . .   *YES          *YES, *NO                 
                                                                           

[解説]

コマンド………. 文書化するコマンドの名前とライブラリー名を指定する。

TO ディレクトリー……… 文書化されたHTMLを保管するストリーム・ファイルを入れる
             ディレクトリー名を指定する。        
             このディレクトリー名は存在していなければならない。

TOストリーム・ファイル…. 生成するHTMLファイルの名前。
              初期値の *CMD とすると(ライブラリー名)_(コマンド名)
として生成される。
              この例の場合では CHAO.COMS_DSPDBSREF.HTML として生成される。

ファイルの置き換え…….. 既存のHTMLファイルがあれば置換える

[コマンド: DSPDBSREFの実行 ]

                      データ・ベース参照表示  (DSPDBSREF)                  
                                                                           
 選択項目を入力して,実行キーを押してください。                            
                                                                           
 プログラム  . . . . . . . . . .   *ALL           名前 , *ALL              
   ライブラリー  . . . . . . . .     *ALLUSR      名前 , *LIBL, *LIBL...   
 出力  . . . . . . . . . . . . .   *             *, *PRINT, *OUTFILE       
 ファイル  . . . . . . . . . . .   SHOHIN         名前                     
   ライブラリー  . . . . . . . .     QTRFIL       名前 , *LIBL, *CURLIB    
 オブジェクト・タイプ  . . . . .   *PGM          *PGM, *SQLPKG, *SRVPGM... 
                                                                           

[解説]

コマンド: DSPDBSREF は指定したファイルを使用しているプログラムを
調べるコマンドである。
各パラメータにカーソルを合わせてF1キーを押すとパラメータの説明が
表示されパラメータ以外にカーソルを合わせてF1キーを押すと
コマンドそのものの説明が表示される。

[コマンド: DSPDBSREF ]

0001.00              CMD        PROMPT(' データ・ベース参照表示 ') +                
0002.00                           PMTFILE(QCPFPMT *DYNAMIC) MSGF(QCPFMSG) +         
0003.00                           HLPID(DSPDBSREF) +                                
0004.00                           HLPPNLGRP(CHAO.COM/DSPDBSREFH)                    
0005.00              PARM       KWD(PGM) TYPE(PGM) +                                
0006.00                           PROMPT(' プログラム ')                            
0007.00  PGM:        QUAL       TYPE(*NAME) LEN(10) DFT(*ALL) SPCVAL((*ALL))        
0008.00              QUAL       TYPE(*NAME) LEN(10) DFT(*ALLUSR) +                  
0009.00                           SPCVAL((*LIBL) (*LIBL) (*CURLIB) +                
0010.00                           (*USRLIBL) (*ALLUSR) (*ALL)) +                    
0011.00                           PROMPT(' ライブラリー ')                          
0012.00              PARM       KWD(OUTPUT) +                                       
0013.00                         TYPE(*CHAR) +                                       
0014.00                         LEN(8) +                                            
0015.00                         RSTD(*YES) +                                        
0016.00                         DFT(*) +                                            
0017.00                         SPCVAL( +                                           
0018.00                           (* ) +                                            
0019.00                           (*PRINT) +                                        
0020.00                           (*OUTFILE)) +                                     
0021.00                         EXPR(*YES) +                                        
0022.00                         PROMPT(' 出力 ')                                    
0023.00              PARM       KWD(FILE) TYPE(FILE) +                              
0024.00                           PROMPT(' ファイル ')                  
0025.00  FILE:       QUAL       TYPE(*NAME) LEN(10) MIN(1)              
0026.00              QUAL       TYPE(*NAME) LEN(10) DFT(*LIBL) +        
0027.00                           SPCVAL((*LIBL) (*CURLIB)) +           
0028.00                           PROMPT(' ライブラリー ')              
0029.00              PARM       KWD(OBJTYPE) +                          
0030.00                         TYPE(*CHAR) +                           
0031.00                         LEN(7) +                                
0032.00                         RSTD(*YES) +                            
0033.00                         DFT(*PGM) +                             
0034.00                         SPCVAL( +                               
0035.00                           (*PGM) +                              
0036.00                           (*SQLPKG) +                           
0037.00                           (*SRVPGM) +                           
0038.00                           (*MODULE) +                           
0039.00                           (*QRYDFN)) +                          
0040.00                         PROMPT(' オブジェクト・タイプ ')        
0041.00              PARM       KWD(OUTFILE) +                          
0042.00                         TYPE(OUTFILE) +                         
0043.00                         FILE(*OUT) +                            
0044.00                         CHOICE(*NONE) +                         
0045.00                         PMTCTL(OUTCTL) +                        
0046.00                         PROMPT(' 出力を受け取るファイル ')      
0047.00 OUTFILE:     QUAL       TYPE(*NAME) +                           
0048.00                         LEN(10) +                              
0049.00                         EXPR(*YES)                             
0050.00              QUAL       TYPE(*NAME) +                          
0051.00                         LEN(10) +                              
0052.00                         DFT(*LIBL) +                           
0053.00                         SPCVAL( +                              
0054.00                           (*LIBL ) +                           
0055.00                           (*CURLIB '*CURLIB   ')) +            
0056.00                         EXPR(*YES) +                           
0057.00                         PROMPT(' ライブラリー ')               
0058.00              PARM       KWD(OUTMBR) +                          
0059.00                         TYPE(OUTMBR) +                         
0060.00                         CHOICE(*NONE) +                        
0061.00                         PMTCTL(OUTCTL) +                       
0062.00                         PROMPT(' 出力メンバー・オプション ')   
0063.00 OUTMBR:      ELEM       TYPE(*NAME) +                          
0064.00                         LEN(10) +                              
0065.00                         DFT(*FIRST) +                          
0066.00                         SPCVAL( +                              
0067.00                           (*FIRST )) +                         
0068.00                         EXPR(*YES) +                           
0069.00                         PROMPT(' 出力を受け取るメンバー ')     
0070.00              ELEM       TYPE(*CHAR) +                          
0071.00                         LEN(8) +                               
0072.00                         RSTD(*YES) +                             
0073.00                         DFT(*REPLACE) +                          
0074.00                         SPCVAL( +                                
0075.00                           (*REPLACE) +                           
0076.00                           (*ADD)) +                              
0077.00                         EXPR(*YES) +                             
0078.00                         PROMPT(' レコードの置き換えまたは追加 ') 
0079.00 OUTCTL:      PMTCTL     CTL(OUTPUT) +                            
0080.00                         COND( +                                  
0081.00                           (*EQ '*OUTFILE'))                      
0082.00              DEP        CTL(&OUTPUT *EQ '*OUTFILE') +            
0083.00                         PARM( +                                  
0084.00                           (&OUTFILE *NE ' ')) +                  
0085.00                         MSGID(CPD9861)                           
0086.00              DEP        CTL(&OUTFILE *EQ ' ') +                  
0087.00                         PARM( +                                  
0088.00                           (OUTMBR)) +                            
0089.00                         NBRTRUE(*EQ 0) +                         
0090.00                         MSGID(CPD9867)                           
0091.00              DEP        CTL(&OUTPUT *NE '*OUTFILE') +            
0092.00                         PARM( +                                  
0093.00                           (&OUTFILE *EQ ' ')) +                  
0094.00                         MSGID(CPD9862)                           

[解説]

コマンドのヘルプはCMDパラメータの

0003.00                           HLPID(DSPDBSREF) +                                
0004.00                           HLPPNLGRP(CHAO.COM/DSPDBSREFH)

に定義されておりこのCMDパラメータに定義しておけば
CRTCMD の実行でヘルプを定義する必要はない。

[ヘルプ・パネル・グループ: DSPDBSREFH ]

0001.00 :PNLGRP HLPSHELF=LIST.                                                             
0002.00 .*            -------------------------                                            
0003.00 .*                 ヘルプの定義                                                    
0004.00 .*            -------------------------                                            
0005.00 :HELP    NAME='DSPDBSREF'. プログラム参照表示 - ヘルプ                             
0006.00 :P.                                                                                
0007.00 :PC. プログラム参照表示 (DSPDBSREF) は指定したファイル ( データ・ベース ) を       
0008.00  使用しているプログラムを検索します。                                              
0009.00 :PC. またライブラリーの先頭文字が Q から始まるライブラリーに含まれている           
0010.00  プログラムも検出することができます。                                              
0011.00 :EHELP.                                                                            
0012.00 :HELP    NAME='DSPDBSREF/PGM'. プログラム - ヘルプ                                 
0013.00 :P.                                                                                
0014.00 :PC. 表示される情報のプログラムを指定します。                                      
0015.00 :XH3. プログラム                                                                   
0016.00 :PC. これは必ず *ALL と指定してください。                                          
0017.00 :XH3. ライブラリー                                                                 
0018.00 :PC. これは必ず *ALLUSR と指定してください。                                       
0019.00 :PC.IBM の仕様では *ALLUSR には頭 Q から始まるライブラリー名は                     
0020.00  除外されて含まれませんが、この DSPDBSREF コマンドでは                             
0021.00 Q から始まるライブラリーも漏れなく検査することができます。                         
0022.00 :EHELP.                                                                            
0023.00 :HELP    NAME='DSPDBSREF/FILE'. ファイル - ヘルプ                                  
0024.00 :P.                                                                     
0025.00 :PC. このファイルが使われているプログラムを検索します。                 
0026.00 :XH3. ファイル                                                          
0027.00 :PC. 検索するファイル名を指定してください。                             
0028.00 :PC. ファイルが保管されているライブラリー名を指定してください。         
0029.00 :EHELP.                                                                 
0030.00 :HELP    NAME='DSPDBSREF/OUTPUT'. 出力  (OUTPUT) -ヘルプ               
0031.00 :P.                                                                     
0032.00 :PC. コマンドからの出力がどこに送られるかを指定します。                 
0033.00 :XH3.*                                                                  
0034.00 :PC. 出力は表示されるか(対話式ジョブによって要求された場合 ),          
0035.00  あるいはジョブのスプール出力で印刷されます(バッチ・ジョブ ) によって  
0036.00  要求された場合 ) 。                                                    
0037.00 :XH3.*PRINT                                                             
0038.00 :PC. 出力はジョブのスプール出力で印刷されます。                         
0039.00 :XH3.OUTFILE                                                            
0040.00 :PC. 出力は,   出力を受け取るファイル (OUTFILE)   パラメータで         
0041.00  指定されたデータベース・ファイルに送られます。                         
0042.00 :EHELP.                                                                 
0043.00 :HELP    NAME='DSPDBSREF/OBJTYPE'. オブジェクト・タイプ  (OBJTYPE)      
0044.00 :P.                                                                     
0045.00 :PC. 情報が表示されるオブジェクト・タイプを指定します。                 
0046.00 :XH3.*PGM                                                               
0047.00 :PC. プログラム情報だけが表示されます。                                 
0048.00 :XH3.*ALL                                                                          
0049.00 :PC. プログラム情報および SQL パッケージ情報が表示されます。                       
0050.00 :XH3.*SQLPKG                                                                       
0051.00 :PC.SQL パッケージ情報だけが表示されます。                                         
0052.00 :XH3.*SRVPGM                                                                       
0053.00 :PC. サービス・プログラム情報が表示されます。                                      
0054.00 :XH3.*MODULE                                                                       
0055.00 :PC. モジュール情報が表示されます。                                                
0056.00 :XH3.*QRYDFN                                                                       
0057.00 :PC.QUERY 定義情報が表示されます。                                                 
0058.00 :EHELP.                                                                            
0059.00 :HELP    NAME='DSPDBSREF/OUTFILE'. 出力を受け取るファイル  (OUTFILE) -ヘルプ      
0060.00 :P.                                                                                
0061.00 :PC. コマンドの出力が送られるデータベース・ファイルを指定します。                  
0062.00  ファイルが存在しない場合には,このコマンドによって指定されたライブラリーに        
0063.00  データベース・ファイルが作成されます。                                            
0064.00  ファイルが作成される場合には,ファイルの共通権限はファイルが作成される            
0065.00  ライブラリーに指定された作成権限と同じものになります。                            
0066.00  ライブラリーの作成権限を表示するにはライブラリー記述表示 (DSPLIBD) コマンドを     
0067.00  使用してください。                                                                
0068.00 :XH3. 修飾子 1: 出力を受け取るファイル                                             
0069.00 :XH3. 名前                                                                         
0070.00 :PC. コマンド出力が送られる先のデータベース・ファイルの名前を指定してください。    
0071.00 :XH3. 修飾子 2: ライブラリー                                                       
0072.00 :XH3.*LIBL                                                                       
0073.00 :PC. ファイルを見つけるために,ライブラリー・リストが使用されます。              
0074.00  ファイルが見つからない場合には,現行ライブラリーにファイルが作成されます。      
0075.00  現行ライブラリーが存在していない場合には,ファイルは QGPL ライブラリーに        
0076.00  作成されます。                                                                  
0077.00 :XH3.*CURLIB                                                                     
0078.00 :PC. ファイルを見つけるためにスレッドの現行ライブラリーが使用されます。          
0079.00  スレッドの現行ライブラリーとして指定されているライブラリーがない場合,          
0080.00 QGPL ライブラリーが使用されます。                                                
0081.00 :XH3. 名前                                                                       
0082.00 :PC. 検索するライブラリーの名前を指定してください。                              
0083.00 :XH3. 注 :                                                                       
0084.00 :PC. 出力ファイル形式は,ライブラリー QSYS のシステム・ファイル                  
0085.00 QADSPPGM の QWHDRPPR と同じでなければなりません。                                
0086.00 OUTFILE 形式の詳細については, IBM I INFORMATION CENTER                          
0087.00 (HTTP://WWW.IBM.COM/SYSTEMS/I/INFOCENTER/) の                                    
0088.00  「データ・ベース」カテゴリーに示されています。                                  
0089.00 :EHELP.                                                                          
0090.00 :HELP    NAME='DSPDBSREF/OUTMBR'. 出力メンバー・オプション  (OUTMBR) -ヘルプ    
0091.00 :P.                                                                              
0092.00 :PC. コマンドの出力を受け取るデータベース・ファイル・メンバーの名前を指定します  
0093.00 :XH3. 要素 1: 出力を受け取るメンバー                                             
0094.00 :XH3.*FIRST                                                                      
0095.00 :PC. ファイル中の最初のメンバーが出力を受け取ります。                            
0096.00 OUTMBR(*FIRST) が指定されていて,メンバーが存在していない場合には                
0097.00  システムが   出力を受け取るファイル (OUTFILE) パラメーターに指定されたファイル  
0098.00  の名前を使用してメンバーを作成します。                                          
0099.00  メンバーが既に存在している場合、その既存メンバーの終わりに新規レコードを追加す  
0100.00  るのか,あるいはそのメンバーをクリアして新規レコードを追加するのかを            
0101.00  選択することができます。                                                        
0102.00 :XH3. 名前                                                                       
0103.00 :PC. 出力を受け取るファイル・メンバーの名前を指定してください。                  
0104.00  存在していない場合には,システムが作成します。                                  
0105.00 :XH3. 要素 2: レコードの置き換えまたは追加                                       
0106.00 :XH3.*REPLACE                                                                    
0107.00 :PC. システムは,既存のメンバーを消去し,新しいレコードを追加します。            
0108.00 :XH3.*ADD                                                                        
0109.00 :PC. システムは,既存のレコードの終わりに新しいレコードを追加します。            
0110.00 :EHELP.                                                                          
0111.00 :EPNLGRP.                                                                        

[コンパイル]

CRTPNLGRP PNLGRP(OBJLIB/DSPDBSREFH) SRCFILE(SRCLIB/QHLPSRC) AUT(*ALL)

[解説]

ヘルプ・パネル・グループのソースは非常に簡単で

0001.00 :PNLGRP HLPSHELF=LIST.
 :
0111.00 :EPNLGRP.

のあいだに

:HELP    NAME=(HELP名)
 :
:EHELP.

のHELPタグを入れるだけである。
HELP名はコマンド全体の説明文はHELP名=コマンド名として
パラメータは HELP名=’コマンド名/パラメータ名’として構成する。
:P.は改行であり:PC,から説明を入れる。
:XH3.は高輝度の見出しである。
これだけ覚えればほとんどすべてのヘルプを作ることができる。
これらを用意してGENCMDDOCを実行すると次のようなHTMLが
生成される。

生成された文書
①コマンド全体のヘルプの説明

②パラメータ一覧
 
③パラメータの説明
 

[解説]

大まかには
①コマンド全体のヘルプの説明
②パラメータ一覧
③パラメータの説明

のようにしてIBM Knowledge Center と同じような文書HTMLが生成される。
オフィスクアトロではHTMLのあいだにコマンド実行画面を撮って
それを挿入して次のようなHTMLに仕上げている。

[解説]

画面イメージはWindowsのALT + PrintScreen で画像をクリップ・ボードにコピーして
Windowsのペイントでそれを Ctrl + V で貼り付けて後は大きさを調整して
PNGとして保存すればよい。

[文書化HTMLの表示]

HTMLを社内で表示するには HTTPサーバーを起動しておいて
ブラウザのURL欄に

http://(IPアドレス)/(IFSパス.HTML)

で表示することができる。
AutoWebやSpoolライターVer5.0のユーザーであれば
既にHTTPサーバーが起動されているのでブラウザにURLを指定するだけで
表示するとこができる。

上記の処理でGENCMDDOCを使ってコマンドを文書化することができる。
このようにすべての業務の出発点をコマンドにしておけば
文書化も簡単にできる。
コマンドがいかに大切であるかがおわかり頂けたと思う。